Re: gEDA-user: passing parameters to a subckt

[al davis <ad252@xxxxxxxxxxxxxxxx>]

On Sunday 25 April 2010, kai-martin knaak wrote:
> 6) Opamps: 
>      a) An ideal opamp with essentially infinite
>  amplification, infinite   slew rate, zero bias current, no
>  input offset, etc. 

Here's an op-amp:

* Generic op-amp behavioral model
.subckt opamp (out+ out- in+ in-)
.param gain=100k sr=1e99 clip=1e99 gbp=1e99
.param cc='1/(6.283185*gbp)'
.param ilim='cc*sr'
G1 (0 1 in+ in-) pwl ('-2*ilim','-ilim','-ilim','-ilim','ilim','ilim','2*ilim','ilim')
R1 (1 0) 'gain'
Cc (1 0) 'cc'
E1 (out+ out- 1 0)  pwl ('-2*clip','-clip','-clip','-clip','clip','clip','2*clip','clip')
.ends

You can specify:
gain = open loop gain
clip = output clipping voltage
sr = slew rate (volts per second)
gbp = gain bandwidth product

There are default values, in case you don't want to specify.

To call:
X1 (out 0 in+ in-) opamp gain=10k gbp=1meg clip=13 sr='5/1e-6'


_______________________________________________
geda-user mailing list
geda-user@xxxxxxxxxxxxxx
http://www.seul.org/cgi-bin/mailman/listinfo/geda-user